YAC Interview Kit may control quotas during a survey.
Often, maximum size of the sample is defined by the survey's client.
Moreover, this sample is usually divided into several subgroups that have their own limits defined
(for instance, so many men and women, so many users of client's product and the competition's product, etc.).
In this text we will show how these definitions may be introduced in YIK's scripting language.
There are three levels at which a limit may be defined:
- On the total number of interviews.
-
On the number of interviews in groups defined by a response or responses to a single question
(such as sex, age ranges, etc.).
-
On the number of interviews in groups defined by combined responses to several questions
(such as in the "cells" of a sex by age groups crosstab).
Below, we will stick to the example given above - quota limits on sex and age groups.
Plus a quota limit on which is the product that respondents buy most often.
Let's say that our client needs to following distribution of respondents:
| Sex \ Age |
18-24 |
25-34 |
35-55 |
Total |
| men |
12 |
10 |
26 |
48 |
| women |
13 |
14 |
25 |
52 |
| Total |
25 |
24 |
51 |
100 |
So, we want at most 100 respondents; 48 men, 52 women; etc.
Moreover, we have 4 product groups and we want at most 25 respondents in each product group
(we will treat this condition independently from the first one).
First, we should assign quota identifiers to the questions that take part in quota control.
A quota identifier is the text "quota_" followed by a number from 1 to 5.
So, let's choose the following identifiers:
| quota_1 |
sex |
| quota_2 | age groups |
| quota_3 | product usage |
Now we are ready to define quota limits in the quota section
and respective questions in the questionnaire section.
First, let's take a look at the quota section:
def quota
// Sex x age groups:
def limit max = 12; quota_1 = m; quota_2 = 18:24; end;
def limit max = 13; quota_1 = f; quota_2 = 18:24; end;
def limit max = 10; quota_1 = m; quota_2 = 25:34; end;
def limit max = 14; quota_1 = f; quota_2 = 25:34; end;
def limit max = 26; quota_1 = m; quota_2 = 35:55; end;
def limit max = 25; quota_1 = f; quota_2 = 35:55; end;
// Product usage:
def limit max = 25; quota_3 = a; end;
def limit max = 25; quota_3 = b; end;
def limit max = 50; quota_3 = c, d; end;
end;
The first 6 limits are defined for the sex / age groups;
quota_1 specifies the identifiers of responses from the question about respondent's sex,
quota_2 specifies ranges of values from the question about respondent's age.
The last 4 limits are defined for product groups -
here, quota_3 specifies the identifiers of products/brands from the question about usage.
We changed the condition a bit to show how quota limits may be defined:
we want 25 of Product A and Product B users each, but we want a total of 50 users of the other 2 products
(without splitting up those 2 products into 2 separate quota limits).
Next, let's take a look at the questionnaire section:
def questionnaire
def question
id = sex;
text = "Please specify your sex:";
quota = quota_1;
def response id = m; text = "Male"; end;
def response id = f; text = "Female"; end;
end;
def question
id = age;
text = "Please specify your age:";
type = form;
def response id = age; text = "Age in years"; numeric = 18:55; quota = quota_2; end;
end;
def question
id = freq;
text = "Which product do you use most often?";
quota = quota_3;
rand = 1;
def response id = a; text = "Product A"; end;
def response id = b; text = "Product B"; end;
def response id = c; text = "Product C"; end;
def response id = d; text = "Product D"; end;
end;
. . .
end;
First thing to note: quota questions should be at the beginning of the questionnaire.
After all, we don't want to close interviews that are more advanced than at most several questions from the start.
(If we have sensitive questions that we want to ask at the end of the interview, for instance,
we may still do so, but these questions should be left out of the quota mechanism -
stopping an interview near the end is not acceptable by respondents.)
The first question is pretty straightforward - responses with their identifiers are mapped to quota_1's identifiers.
However, there are no limits defined for sex only, so quotas will not be checked after the first question.
The second question is a form question with one numeric line to be filled out - with the respondents age.
Age ranges are defined in quota_2. Because this type of question may specify several such lines,
the quota mapping must go into the response section
(and not, like it is in the other two questions, in the question section).
Since after this question we have full information to check the first 6 quota limits, the program does so.
If the respective limit is exceeded (for instance, 14th woman aged 18-24), the interview will be stopped.
The third question is asked if the respondent gets through the first quota check.
Again, this question is pretty simple, except that it maps to the last 4 quota limits (quota_3).
If there are already 25 respondents in the selected limit (and we have a 26th respondent), the interview will be stopped.
These limits are checked independently from the first 6 limits,
so, at least theoretically, we can get all women aged 18-24 in the group of Product A users.
Although not very probable, all such situations should by analyzed in detail and discussed with the survey's client.
Maybe these limits should be combined with the first 6 limits so that collected data results in an even distribution
across all 3 characteristics?
All in all, the quota mechanism
in YAC Interview Kit is quite robust
and allows for very detailed control of the sizes of the various groups of respondents.
Top
|
Texts
